韩国久久久久久,欧美极品少妇videossex,亚洲欧美久久234

??????? 游標在數據庫領域被廣泛使用，尤其是對于需要將SQL語句返回的數據集進行逐行處理的時候。這為數據處理提供了極大的便利性，然游標的不當
使用從某種程度上而言會降低數據庫的性能。下面的是一個來自生產環境的實際例子，由于使用了參數游標，所以引發了多次遍歷。

一、源代碼

-->下面的procedure用于為trade生成一個新的contract_num，并將其更新到對應的記錄

PROCEDURE assign_contract_num( businessdate_in trade_client_tbl.trade_date%TYPE, err_num OUT NUMBER, err_msg OUT VARCHAR2 ) IS

   myspname   CONSTANT VARCHAR2( 100 ) := 'bo_trd_dayend_pkg.assign_contract_num';

   debugpos            bo_common_pkg.debug_pos_type := 0;



	 -->注意此處的游標，此為參數游標，定義了兩個輸入參數一個是orderside，一個是inputdate

	 -->參數游標的參數應當作為SQL語句的過濾條件，如本例中的where子句的謂詞信息

   CURSOR validtradedate( orderside_in trade_client_tbl.order_side%TYPE, inputdate_in trade_client_tbl.input_date%TYPE ) IS

      SELECT trade_date

      FROM   trade_client_tbl

      WHERE  is_valid_trade = 'Y' AND input_date = inputdate_in AND order_side = orderside_in AND contract_num IS NULL

      GROUP BY trade_date

      ORDER BY trade_date;



	 -->再次定義了一個參數游標，此時帶有三個參數

   CURSOR validtradecur( orderside_in    trade_client_tbl.order_side%TYPE

                       , tradedate_in    trade_client_tbl.trade_date%TYPE

                       , inputdate_in    trade_client_tbl.input_date%TYPE ) IS

      SELECT grp_ref_id, order_side

      FROM   trade_client_tbl

      WHERE  is_valid_trade = 'Y' AND trade_date = tradedate_in AND input_date = inputdate_in 

      AND order_side = orderside_in AND contract_num IS NULL

      GROUP BY grp_ref_id, order_side

      ORDER BY grp_ref_id;



   syscontract_idx     PLS_INTEGER;     -->聲明變量

   syscontract_num     VARCHAR2( 20 );  -->聲明變量

BEGIN

   err_num     := bo_common_pkg.c_suc_general;

   debugpos    := 5;



   -- *** Buy Trades Contract No. ***

   FOR trddaterec IN validtradedate( 'B', businessdate_in )  -->開始使用參數遍歷游標

   LOOP

      BEGIN

         debugpos    := 10;



         SELECT MAX( contract_num )   -->求當月且類型為B，最大的contract_num號

         INTO   syscontract_num

         FROM   trade_client_vw

         WHERE  trade_date LIKE

                   SUBSTR( trddaterec.trade_date, 1, 6 )

                   || '%'

                AND order_side = 'B';



         IF syscontract_num IS NOT NULL THEN    -->當非空值時，調用函數從中取出contract_num的首部

            debugpos    := 15;

            syscontract_idx := extract_contract_num_idx( syscontract_num );

         ELSE

            syscontract_idx := 0;

         END IF;

      END;



      debugpos    := 20;



      FOR validtraderec IN validtradecur( 'B', trddaterec.trade_date, businessdate_in )  -->使用參數遍歷第二個游標

      LOOP                                               -->注意此時的一個參數為上一個游標獲得的結果集(trddaterec.trade_date)

         syscontract_idx :=                              -->此時syscontract_idx的值增加1

            syscontract_idx

            + 1;

         syscontract_num := format_contract_num( validtraderec.order_side, trddaterec.trade_date, syscontract_idx );-->格式化contract_num

         debugpos    := 25;

         DBMS_OUTPUT.put_line(   'B - '

                              || validtraderec.grp_ref_id

                              || ' - '

                              || syscontract_num );



         UPDATE trade_client_tbl                       -->將生成的syscontract_num更新到對應記錄的contract_num

         SET    contract_num = syscontract_num

         WHERE  grp_ref_id = validtraderec.grp_ref_id;

      END LOOP;

   END LOOP;



   -- *** Sell Trades Contract No. ***  -->下面的這段代碼則等同于上一個處理，所不同的是處理所有類型為S的記錄

   FOR trddaterec IN validtradedate( 'S', businessdate_in )   

   LOOP

      BEGIN

         debugpos    := 35;



         SELECT MAX( contract_num )

         INTO   syscontract_num

         FROM   trade_client_vw

         WHERE  trade_date LIKE

                   SUBSTR( trddaterec.trade_date, 1, 6 )

                   || '%'

                AND order_side = 'S';



         IF syscontract_num IS NOT NULL THEN

            debugpos    := 40;

            syscontract_idx := extract_contract_num_idx( syscontract_num );

         ELSE

            syscontract_idx := 0;

         END IF;

      END;



      debugpos    := 45;



      FOR validtraderec IN validtradecur( 'S', trddaterec.trade_date, businessdate_in )

      LOOP

         syscontract_idx :=

            syscontract_idx

            + 1;

         syscontract_num := format_contract_num( validtraderec.order_side, trddaterec.trade_date, syscontract_idx );

         debugpos    := 50;

         DBMS_OUTPUT.put_line(   'S - '

                              || validtraderec.grp_ref_id

                              || ' - '

                              || syscontract_num );



         UPDATE trade_client_tbl                         

         SET    contract_num = syscontract_num

         WHERE  grp_ref_id = validtraderec.grp_ref_id;

      END LOOP;

   END LOOP;



   -- Update ACC_POS_HIST_TBL contract num field.   -->最后將所有新生存的contract_num更新到歷史記錄表

   BEGIN

      UPDATE acc_pos_hist_tbl aph

      SET    aph.contract_num =

                (SELECT DISTINCT tc.contract_num

                 FROM   trade_client_vw tc

                 WHERE  aph.trans_num = tc.grp_ref_id )

      WHERE      aph.contract_num IS NULL

             AND aph.trans_type_cd LIKE 'TD%'

             AND EXISTS

                    (SELECT 1

                     FROM   trade_client_vw tc

                     WHERE  aph.trans_num = tc.grp_ref_id AND tc.contract_num IS NOT NULL);

   END;

END;



-->分析：

-->1.源代碼中的主要目的是為表trade_client_tbl中新的trade生成contract_num

-->2.由于存在兩種不同類型的order_side，一個為B(Buy)，一個為S(Sell)，所有使用了參數游標來完成

-->3.使用了兩次嵌套循環(loop)

-->4.代碼存在冗余現象。即僅僅是類型的不同而導致了游標需要多次的訪問表trade_client_tbl

二、代碼改進

-->通過上面的分析考慮將類型為B和S的進行合并處理，避免多次掃描原始表。(僅列出改進部分)

-->由于不能確保游標trade_date_cur得到的記錄唯一，所以在此仍然使用了兩次嵌套，但避免針對不同類型B和S單獨處理。

-->兩次游標仍然是原來的SQL語句。如果得到的trade_date唯一，則主循環僅循環一次，否則得到的trade_date多次則循環多次。

FOR trade_date_cur IN (SELECT trade_date

                       FROM   trade_client_tbl

                       WHERE  is_valid_trade = 'Y' AND input_date = businessdate_in AND contract_num IS NULL

                       GROUP BY trade_date

                       ORDER BY trade_date )

LOOP

   FOR trade_cur

      IN (SELECT grp_ref_id, order_side, trade_date

          FROM   trade_client_tbl

          WHERE  is_valid_trade = 'Y' AND input_date = businessdate_in AND contract_num IS NULL 

          AND trade_date = trade_date_cur.trade_date

          GROUP BY grp_ref_id, trade_date, order_side

          ORDER BY 1, 2, 3 )

   LOOP

      v_counter   :=

               v_counter

               + 1;

      CASE                                          -->此處使用了case語句來進行區分order_side為B或S

         WHEN trade_cur.order_side = 'B' THEN       -->由于可知的是任意一條trade記錄的order_side不是類型為B就是為S

            SELECT MAX( contract_num )              -->因此所需要解決的是根據類型的不同得到不同的最大的contract_num

            INTO   syscontract_num                  -->并在此基礎之上來生成新的contract_num

            FROM   trade_client_vw

            WHERE  trade_date LIKE                  -->實際上這個謂詞trade_date還可以縮小范圍，因為每一天生成的首部是不同的

                      SUBSTR( trade_cur.trade_date, 1, 6 )

                      || '%'

                   AND order_side = 'B';

         ELSE

            SELECT MAX( contract_num )

            INTO   syscontract_num

            FROM   trade_client_vw

            WHERE  trade_date LIKE

                      SUBSTR( trade_cur.trade_date, 1, 6 )

                      || '%'

                   AND order_side = 'S';

      END CASE;



      IF syscontract_num IS NOT NULL THEN

         --   debugpos := 15;

         syscontract_idx := extract_contract_num_idx( syscontract_num );

      ELSE

         syscontract_idx := 0;

      END IF;

     

      syscontract_idx :=

         syscontract_idx

         + 1;

      syscontract_num := format_contract_num( trade_cur.order_side, trade_cur.trade_date, syscontract_idx );

      DBMS_OUTPUT.put_line( 'Current syscontract_num is '

                                 || syscontract_num );

      UPDATE trade_client_tbl

      SET    contract_num = syscontract_num

      WHERE  grp_ref_id = trade_cur.grp_ref_id;

   END LOOP;

END LOOP;

三、調整后結果比對

-->下面是調整前的測試

goex_admin@SYBO2> DECLARE

  2    businessdate_in CHAR(8);

  3    err_num NUMBER;

  4    err_msg VARCHAR2(32767);

  5  

  6  BEGIN

  7    businessdate_in := '20111228';

  8    err_num := NULL;

  9    err_msg := NULL;

 10  

 11    goex_admin.BO_TRD_DAYEND_PKG.assign_contract_num ( businessdate_in, err_num, err_msg );

 12  

 13    DBMS_OUTPUT.Put_Line('ERR_NUM = ' || TO_CHAR(err_num));

 14    DBMS_OUTPUT.Put_Line('ERR_MSG = ' || err_msg);

 15  

 16    DBMS_OUTPUT.Put_Line('');

 17  

 18    COMMIT;

 19  END;

 20  /

B - 03586401 - B1112009143

B - 03586404 - B1112009144

B - 03586416 - B1112009145

........



ERR_NUM = 0

ERR_MSG =



PL/SQL procedure successfully completed.



Elapsed: 00:04:21.97



-->下面是調整后測試的結果，將assign_contract_num封裝到一個臨時的包

goex_admin@SYBO2> DECLARE

  2    businessdate_in CHAR(8);

  3    err_num NUMBER;

  4    err_msg VARCHAR2(32767);

  5  

  6  BEGIN

  7    businessdate_in := '20111228';

  8    err_num := NULL;

  9    err_msg := NULL;

 10  

 11    goex_admin."BO_TRD_DAYEND_PKG_tmp".assign_contract_num ( businessdate_in, err_num, err_msg );

 12    COMMIT;

 13  END;

 14  /

Current syscontract_num is B1112009143

Current syscontract_num is S1112009340

Current syscontract_num is S1112009341

........

The total count is 797



PL/SQL procedure successfully completed.



Elapsed: 00:00:03.06

goex_admin@SYBO2> spool off;



-->從上面的前后結果對比可知總計797條記錄原來所需的時間為4:21.97s，調整之后僅為3.06s。如果記錄多的話，差異應該更大

-->Author:?Robinson?Cheng????????? 

-->Blog:???http://blog.csdn.net/robinson_0612

四、總結
1、參數游標從某種程度上而言，增加了游標的靈活性。即一次定義，多次調用。
2、對基于相同表使用參數游標將會導致對表對象的多次數據讀取，增加了I/O開銷。

3、盡可能的縮小數據中間結果集，如上面的獲得最大的contract_num，由于生成的其唯一性，我們可以將搜索范圍限制在一周或當天。

五、更多參考

啟用用戶進程跟蹤

父游標、子游標及共享游標

綁定變量及其優缺點

dbms_xplan之display_cursor函數的使用

dbms_xplan之display函數的使用

執行計劃中各字段各模塊描述

使用 EXPLAIN PLAN 獲取SQL語句執行計劃

更多文章、技術交流、商務合作、聯系博主

微信掃碼或搜索：z360901061

微信掃一掃加我為好友

QQ號聯系： 360901061

您的支持是博主寫作最大的動力，如果您喜歡我的文章，感覺我的文章對您有幫助，請用微信掃描下面二維碼支持博主2元、5元、10元、20元等您想捐的金額吧，狠狠點擊下面給點支持吧，站長非常感激您！手機微信長按不能支付解決辦法：請將微信支付二維碼保存到相冊，切換到微信，然后點擊微信右上角掃一掃功能，選擇支付二維碼完成支付。

【本文對您有幫助就好】元

2元

5元

10元

20元

自定義

日韩久久久精品,亚洲精品久久久久久久久久久,亚洲欧美一区二区三区国产精品 ,一区二区福利